***********************************************************;
*  Research Computing Services                            *;
*  Introduction to SAS                                    *;
***********************************************************;
 
***********************************************************;
*  SAS ODS                                                *;
*                                                         *;
***********************************************************;
* Read more:                                               ;
*    general:  https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.5/odsug/p05xa6eans9jw2n1lsc8li0r8waw.htm  *;
*    ODS Table Names: https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.5/procstat/procstat_univariate_odstables.htm ;
*    ODS Graphics: https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.5/procstat/procstat_univariate_details92.htm ;
* ;


/* Include sas program that sets input library */
%include "setup.sas";


* Turn trace on to view the names of the tables generated by the univariate proc;
* Check the output in the log;
ods trace on;
proc univariate data=mydata.med_visits;
	var Height ;
run;
ods trace off;


* Once we know the names of the tables, we can select them by name;
ods select BasicMeasures ExtremeObs;
proc univariate data=mydata.med_visits;
	var Height ;
run;



* Univariate normality test;
ods select TestsforNormality;
proc univariate data=mydata.med_visits normal;
	var Height ;
run;


* Run normality test for the cars dataset from sashelp library;
ods select TestsforNormality;
proc univariate data=sashelp.cars normal;
	var weight ;
run;

* Calculate Sample T-test;
ods select TestsForLocation;
proc univariate data=sashelp.cars mu0=4500;
	var weight ;
run;